import mods.thaumcraft.Research;
import mods.thaumcraft.Infusion;

val BeeCatalystIchor = <customthings:block0:1>;
val BeeCatalystCelestial = <customthings:block0>;
val MagicalApiary = <MagicBees:magicApiary>;
val Ichorium = <ThaumicTinkerer:kamiResource:2>;
val Ichorcloth = <ThaumicTinkerer:kamiResource:1>;
val GaiaSpirit = <Botania:manaResource:5>;
val CelestialPearl = <ThaumicTinkerer:skyPearl>;

Research.addResearch("BEE_ICHOR", "TT_CATEGORY", "lucrum 5, lux 5, spiritus 5, humanus 5", 10, 10, 100, BeeCatalystIchor);
Research.addPage("BEE_ICHOR", "BEE_ICHOR.research_page.1");
game.setLocalization("en_US", "BEE_ICHOR.research_page.1", "With the discovery of Ichor, you feel the need to breed a bee that can make it. This will require a catalyst, however. Infused with Ichorium and Ichorcloth, this block should do.");
game.setLocalization("en_US", "tc.research_name.BEE_ICHOR", "Deity Bee Catalyst");
game.setLocalization("en_US", "tc.research_text.BEE_ICHOR", "Godlike bees!");
Research.addPrereq("BEE_ICHOR","ICHOR");
Research.setConcealed("BEE_ICHOR", true);

Research.addResearch("BEE_CELESTIAL", "TT_CATEGORY", "lucrum 5, lux 5, spiritus 5, iter 5, alienis 5", 20, 10, 100, BeeCatalystCelestial);
Research.addPage("BEE_CELESTIAL", "BEE_CELESTIAL.research_page.1");
game.setLocalization("en_US", "BEE_CELESTIAL.research_page.1", "With the amount of Celestial Pearls you seem to need, you decide that a bee that can produce them would be great. This will require a catalyst though, similarly to the Deity bee.");
game.setLocalization("en_US", "tc.research_name.BEE_CELESTIAL", "Celestial Bee Catalyst");
game.setLocalization("en_US", "tc.research_text.BEE_CELESTIAL", "Rulers of the heavens!");
Research.addPrereq("BEE_CELESTIAL","WARP_GATE");
Research.setConcealed("BEE_CELESTIAL", true);


game.setLocalization("tile.customthings.celestialbeecatalyst.name","Celestial Bee Catalyst");
game.setLocalization("tile.customthings.ichorbeecatalyst.name","Deity Bee Catalyst");

Infusion.addRecipe("BEE_ICHOR",MagicalApiary,[Ichorium,Ichorcloth,Ichorium,Ichorcloth,Ichorium,Ichorcloth,Ichorium,Ichorcloth,Ichorium,Ichorcloth,Ichorium,Ichorcloth],"lucrum 32, lux 64, spiritus 128, humanus 64",BeeCatalystIchor,24);
Research.addInfusionPage("BEE_ICHOR",BeeCatalystIchor);

Infusion.addRecipe("BEE_CELESTIAL",MagicalApiary,[CelestialPearl,GaiaSpirit,CelestialPearl,GaiaSpirit,CelestialPearl,GaiaSpirit,CelestialPearl,GaiaSpirit,CelestialPearl,GaiaSpirit,CelestialPearl,GaiaSpirit],"lucrum 32, lux 64, spiritus 128, iter 64, alienis 64",BeeCatalystCelestial,24);
Research.addInfusionPage("BEE_CELESTIAL",BeeCatalystCelestial);

recipes.remove(<gendustry:IndustrialApiary>);
recipes.remove(<gendustry:ApiaryUpgrade:*>);
