import mods.thaumcraft.Arcane;
import mods.thaumcraft.Research;
import mods.thaumcraft.Crucible;
import mods.thaumcraft.Infusion;
import mods.bloodmagic.Alchemy;

val AuraConductingIngot = <ChromatiCraft:chromaticraft_item_crafting:20>;
val PavingStoneWarding = <Thaumcraft:blockCosmeticSolid:3>;
val CrystalCore = <ChromatiCraft:chromaticraft_item_cluster:10>;
val RunicMatrix = <Thaumcraft:blockStoneDevice:2>;
val ArcaneStone = <Thaumcraft:blockCosmeticSolid:6>;
val ArcaneStoneSlab = <Thaumcraft:blockCosmeticSlabStone>;
val VortexPedestal = <aura:auraNodecraftingPedestal>;
val ArcanePedestal = <Thaumcraft:blockStoneDevice:1>;
val WandCapGold = <Thaumcraft:WandCap:1>;
val KitrinoShard = <ChromatiCraft:chromaticraft_item_shard:11>;
val GoldIngot = <minecraft:gold_ingot>;
val GoldNugget = <minecraft:gold_nugget>;
val WandCapThaumium = <Thaumcraft:WandCap:6>;
val ThaumiumIngot = <Thaumcraft:ItemResource:2>;
val ThaumiumNugget = <Thaumcraft:ItemNugget:6>;
val BoostedKitrinoShard = <ChromatiCraft:chromaticraft_item_shard:27>;
val BoostedZambarauShard = <ChromatiCraft:chromaticraft_item_shard:21>;
val GreatwoodRod = <Thaumcraft:WandRod>;
val Livingwoodrod = <Botania:manaResource:3>;
val GreatwoodPlank = <Thaumcraft:blockWoodenDevice:6>;
val ManaSteelIngot = <Botania:manaResource>;
val NodeTransducer = <Thaumcraft:blockStoneDevice:11>;
val AdvancedNodeStabilizer = <Thaumcraft:blockStoneDevice:10>;
val ThaumiumGearBox = <thaumicenergistics:thaumicenergistics.block.golem.gear.box>;
val AlternatingRedstonePump = <aura:auraNodepumpRedstoneAlt>;
val FocalPowder = <ChromatiCraft:chromaticraft_item_tiered:3>;
val HyperEnergeticNitor = <ThaumicTinkerer:brightNitor>;
val ThaumoStaticHarness = <Thaumcraft:HoverHarness>;
val ManaSteelChestplate = <Botania:manasteelChest>;
val UprisingFocus = <ThaumicTinkerer:focusFlight>;
val Aether = <AWWayofTime:aether>;
val AirCrystalCluster = <Thaumcraft:blockCrystal>;
val AirSigil = <AWWayofTime:airSigil>;
val FieryIngot = <TwilightForest:item.fieryIngot>;
val RunicMatrixIngots = <ore:ingotRunicMatrix>;
RunicMatrixIngots.add(FieryIngot);
RunicMatrixIngots.add(AuraConductingIngot);
val PrimordialPearl = <Thaumcraft:ItemEldritchObject:3>;
val DemonBloodShard = <AWWayofTime:demonBloodShard>;
val MimikineticUpheaver3 = <Mimicry:Sparr_Mimikinetic Upheaver:3>;
val MixedCrystalBlock = <thaumicbases:crystalBlock:6>;
val CheatSheet = <Thaumcraft:ItemThaumonomicon:42>;
val Thaumonicon = <Thaumcraft:ItemThaumonomicon>;
val KnowledgeFragment = <Thaumcraft:ItemResource:9>;
val IronNugget = <ore:nuggetIron>;
val TitaniumNugget = <ore:nuggetTitanium>;
val IronCap = <Thaumcraft:WandCap>;
val EldritchEye = <Thaumcraft:ItemEldritchObject>;
val EnergizedVoidCore = <ChromatiCraft:chromaticraft_item_crafting:23>;
val VoidSeed = <Thaumcraft:ItemResource:17>;
val VoidEssence = <ChromatiCraft:chromaticraft_item_crafting:30>;


Arcane.removeRecipe(RunicMatrix);
Arcane.addShaped("INFUSION", RunicMatrix, "ordo 55, perditio 55, aqua 55, terra 55, ignis 55, aer 55", [[RunicMatrixIngots, PavingStoneWarding, RunicMatrixIngots],[PavingStoneWarding, CrystalCore, PavingStoneWarding],[RunicMatrixIngots, PavingStoneWarding, RunicMatrixIngots]]);

Arcane.removeRecipe(ArcanePedestal);
Arcane.addShaped("INFUSION",ArcanePedestal*2, "ordo 10, perditio 10, aqua 10, terra 10, ignis 10, aer 10", [[ArcaneStoneSlab,VortexPedestal,ArcaneStoneSlab],[null,ArcaneStone,null],[ArcaneStone,ArcaneStone,ArcaneStone]]);
Research.refreshResearchRecipe("INFUSION");

Arcane.removeRecipe(WandCapGold);
Arcane.addShaped("CAP_gold",WandCapGold, "ordo 3, ignis 3, aer 3", [[GoldNugget,GoldIngot,GoldNugget],[GoldIngot,KitrinoShard,GoldIngot]]);
Research.refreshResearchRecipe("CAP_gold");

Arcane.removeRecipe(WandCapThaumium);
Arcane.addShaped("CAP_thaumium",WandCapThaumium, "ordo 6, ignis 6, aer 6", [[ThaumiumNugget,ThaumiumIngot,ThaumiumNugget],[ThaumiumIngot,BoostedZambarauShard,ThaumiumIngot],[BoostedKitrinoShard,null,BoostedKitrinoShard]]);
Research.refreshResearchRecipe("CAP_thaumium");

Arcane.removeRecipe(GreatwoodRod);
Arcane.addShaped("ROD_greatwood",GreatwoodRod, "perditio 3", [[null,GreatwoodPlank,Livingwoodrod],[GreatwoodPlank,Livingwoodrod,GreatwoodPlank],[Livingwoodrod,GreatwoodPlank,null]]);
Research.refreshResearchRecipe("ROD_greatwood");

Crucible.removeRecipe(ThaumiumIngot);
Crucible.addRecipe("THAUMIUM", ThaumiumIngot, ManaSteelIngot, "praecantatio 4");
Research.refreshResearchRecipe("THAUMIUM");

Arcane.removeRecipe(NodeTransducer);
Arcane.addShaped("VISPOWER",NodeTransducer,"ordo 100, perditio 100, aqua 100, terra 100, ignis 100, aer 100", [[AlternatingRedstonePump,ThaumiumGearBox,AlternatingRedstonePump],[ThaumiumIngot,AdvancedNodeStabilizer,ThaumiumIngot],[FocalPowder,HyperEnergeticNitor,FocalPowder]]);
Research.refreshResearchRecipe("VISPOWER");

Infusion.removeRecipe(ThaumoStaticHarness);
Infusion.addRecipe("HOVERHARNESS",ManaSteelChestplate,[UprisingFocus,Aether,AirCrystalCluster,AirSigil,AirCrystalCluster,Aether],"volatus 64, potentia 32, machina 32, iter 32", ThaumoStaticHarness, 7);
Research.refreshResearchRecipe("HOVERHARNESS");

Alchemy.addRecipe(PrimordialPearl*2, [PrimordialPearl, MimikineticUpheaver3, MixedCrystalBlock, MixedCrystalBlock, DemonBloodShard], 6, 100000);

Research.addResearch("CHEATYNOMICON", "BASICS", "perditio 10, ordo 10, permutatio 10, potentia 10, praecantatio 10, terminus 10", 2, -4, 100, CheatSheet);
Research.addPage("CHEATYNOMICON", "CHEATYNOMICON.research_page.1");
game.setLocalization("en_US", "CHEATYNOMICON.research_page.1", "You want knowledge. You need knowledge. YOU MUST HAVE KNOWLEDGE. MORE KNOWLEDGE. MOOOOORRRRRREEEEE!");
game.setLocalization("en_US", "tc.research_name.CHEATYNOMICON", "Infinite Knowledge");
game.setLocalization("en_US", "tc.research_text.CHEATYNOMICON", "Raw Knowledge Of The Universe, What Could Possibly Go Wrong?");
mods.thaumcraft.Warp.addToResearch("CHEATYNOMICON", 50);
Research.addPrereq("CHEATYNOMICON","THAUMONOMICON");

Infusion.addRecipe("CHEATYNOMICON",Thaumonicon,[PrimordialPearl,KnowledgeFragment,KnowledgeFragment,KnowledgeFragment,KnowledgeFragment,KnowledgeFragment,KnowledgeFragment],"cognitio 64, praecantatio 64",CheatSheet,10);
Research.addInfusionPage("CHEATYNOMICON",CheatSheet);

Infusion.removeRecipe(EldritchEye);
Infusion.addRecipe("OCULUS",EnergizedVoidCore,[VoidSeed,VoidEssence,VoidEssence,GoldIngot,VoidEssence,VoidEssence],"alienis 64, vacuos 16, tenebrae 16, iter 16",EldritchEye,5);
Research.refreshResearchRecipe("OCULUS");

recipes.remove(IronCap);
recipes.addShaped(IronCap,[[TitaniumNugget,IronNugget,TitaniumNugget],[IronNugget,null,IronNugget]]);
