import mods.bloodmagic.Altar;
import mods.bloodmagic.BloodOrb;
import minetweaker.item.IItemStack;
import mods.bloodmagic.Binding;

val AttunedStoneCharged = <witchery:ingredient:11>;
val NecromanticStone = <witchery:ingredient:64>;
val InfernalAnimus = <witchery:ingredient:45>;
val BloodOrb1 = <AWWayofTime:weakBloodOrb>;
val BloodOrb2 = <AWWayofTime:apprenticeBloodOrb>;
val BloodOrb3 = <AWWayofTime:magicianBloodOrb>;
val BloodAltar = <AWWayofTime:Altar>;
val AuraIngotBlack = <aura:ingotBlack>;
val EngravedCrystallineStone = <ChromatiCraft:chromaticraft_block_pylonstruct:7>;
val DiamondVapor = <witchery:ingredient:29>;
val RuzovaCrystal = <ChromatiCraft:chromaticraft_block_crystal:9>;
val BloodRune = <AWWayofTime:AlchemicalWizardrybloodRune>;
val ArcaneStone = <Thaumcraft:blockCosmeticSolid:6>;
val BlankSlate = <AWWayofTime:blankSlate>;
val HydraBlood = <TwilightForest:item.fieryBlood>;
val AirSigil = <AWWayofTime:airSigil>;
val Aether = <AWWayofTime:aether>;
val GhastTear = <minecraft:ghast_tear>;
val RavenFeather = <TwilightForest:item.tfFeather>;
val ImbuedSlate = <AWWayofTime:imbuedSlate>;
val RuneBasicCapacity = <AWWayofTime:AlchemicalWizardrybloodRune:1>;
val CrystalTank = <ChromatiCraft:chromaticraft_block_tank>;
val BloodTank = <Sanguimancy:BlockBloodTank>;
val TitaniumTank = <Mariculture:tanks:6>;
val RuneDislocation = <AWWayofTime:AlchemicalWizardrybloodRune:2>;
val FluidicEssence = <ChromatiCraft:chromaticraft_item_tiered:9>;
val FluidLinkAnchor = <ChromatiCraft:chromaticraft_item_placer:79>;
val FocalPowder = <ChromatiCraft:chromaticraft_item_tiered:3>;
val TransmissiveDust = <ChromatiCraft:chromaticraft_item_tiered:5>;
val RuneSacrifice = <AWWayofTime:runeOfSacrifice>;
val RuneSelfSacrifice = <AWWayofTime:runeOfSelfSacrifice>;
val ReinforcedSlate = <AWWayofTime:reinforcedSlate>;
val ElementalInscriptionTools = [<AWWayofTime:waterScribeTool>,<AWWayofTime:fireScribeTool>,<AWWayofTime:earthScribeTool>,<AWWayofTime:airScribeTool>] as IItemStack[];
val BasicBotaniaRunes = [<Botania:rune>,<Botania:rune:1>,<Botania:rune:2>,<Botania:rune:3>] as IItemStack[];
val HighDiviningRod = <ProjectE:item.pe_divining_rod_3>;
val RitualDiviner = <AWWayofTime:itemRitualDiviner>;
val PotionFlask = <AWWayofTime:alchemyFlask>;

recipes.remove(BloodAltar);
recipes.addShaped(BloodAltar,[[AuraIngotBlack,null,AuraIngotBlack],[EngravedCrystallineStone,DiamondVapor,EngravedCrystallineStone],[EngravedCrystallineStone,RuzovaCrystal,EngravedCrystallineStone]]);
recipes.addShaped(BloodAltar,[[AuraIngotBlack,null,AuraIngotBlack],[EngravedCrystallineStone,HydraBlood,EngravedCrystallineStone],[EngravedCrystallineStone,RuzovaCrystal,EngravedCrystallineStone]]);

Altar.removeRecipe(BloodOrb1);
Altar.addRecipe(BloodOrb1,AttunedStoneCharged,1,2000,2,1);

Altar.removeRecipe(BloodOrb2);
Altar.addRecipe(BloodOrb2,NecromanticStone,2,5000,5,5);

Altar.removeRecipe(BloodOrb3);
Altar.addRecipe(BloodOrb3,InfernalAnimus,3,25000,20,20);

recipes.remove(BloodRune);
BloodOrb.addShaped(BloodRune,[[ArcaneStone,ArcaneStone,ArcaneStone],[BlankSlate,BloodOrb1,BlankSlate],[ArcaneStone,ArcaneStone,ArcaneStone]]);

recipes.remove(AirSigil);
BloodOrb.addShaped(AirSigil,[[Aether,GhastTear,Aether],[RavenFeather,ImbuedSlate,RavenFeather],[Aether,BloodOrb3,Aether]]);

recipes.remove(RuneBasicCapacity);
BloodOrb.addShaped(RuneBasicCapacity,[[ArcaneStone,CrystalTank,ArcaneStone],[CrystalTank,BloodOrb3,CrystalTank],[ArcaneStone,ImbuedSlate,ArcaneStone]]);
BloodOrb.addShaped(RuneBasicCapacity,[[ArcaneStone,TitaniumTank,ArcaneStone],[BloodTank,BloodOrb3,BloodTank],[ArcaneStone,ImbuedSlate,ArcaneStone]]);

recipes.remove(RuneDislocation);
BloodOrb.addShaped(RuneDislocation,[[ArcaneStone,FluidLinkAnchor,ArcaneStone],[FluidicEssence,BloodOrb3,FluidicEssence],[ArcaneStone,ImbuedSlate,ArcaneStone]]);

recipes.remove(RuneSacrifice);
BloodOrb.addShaped(RuneSacrifice,[[ArcaneStone,ReinforcedSlate,ArcaneStone],[FocalPowder,BloodOrb2,FocalPowder],[ArcaneStone,ReinforcedSlate,ArcaneStone]]);

recipes.remove(RuneSelfSacrifice);
BloodOrb.addShaped(RuneSelfSacrifice,[[ArcaneStone,ReinforcedSlate,ArcaneStone],[TransmissiveDust,BloodOrb2,TransmissiveDust],[ArcaneStone,ReinforcedSlate,ArcaneStone]]);

for i, inscriptiontool in ElementalInscriptionTools {
Altar.removeRecipe(inscriptiontool);
Altar.addRecipe(inscriptiontool,BasicBotaniaRunes[i],3,10000,30,30);
}

recipes.remove(RitualDiviner);
Binding.addRecipe(HighDiviningRod,RitualDiviner);

Altar.removeRecipe(PotionFlask);
Altar.addRecipe(PotionFlask,<Botania:vial:1>,4,25000);
