recipes.remove(<ExtraUtilities:generator:*>);
recipes.remove(<ExtraUtilities:generator.8:*>);
recipes.remove(<ExtraUtilities:generator.64:*>);
recipes.remove(<ExtraUtilities:watering_can:1>);
recipes.remove(<ExtraUtilities:enderCollector>);
recipes.remove(<ExtraUtilities:enderQuarry>);
recipes.remove(<ExtraUtilities:angelRing:*>);
<ExtraUtilities:enderCollector>.addTooltip(format.red("Can't use this, because it breaks stuff..."));

val VoidMetal = <Thaumcraft:ItemResource:16>;
val TransfernodeLiquid = <ExtraUtilities:extractor_base:6>;
val TransfernodeItems = <ExtraUtilities:extractor_base>;
val EnderPearl = <minecraft:ender_pearl>;
val Redstone = <minecraft:redstone>;
val Lapis = <minecraft:dye:4>;
val TitaniumBucket = <Mariculture:bucket_titanium>;
val IronChest = <IronChest:BlockIronChest>;
val TransferPipe = <ExtraUtilities:pipes>;
val ResonatingIngot = <ChromatiCraft:chromaticraft_item_crafting:17>;
val FluidicIngot = <ChromatiCraft:chromaticraft_item_crafting:18>;
val Thaumium = <Thaumcraft:ItemResource:2>;
val EnderInfusedObsidian = <ExtraUtilities:decorativeBlock1:1>;
val PurpleObsidian = <ExtraUtilities:color_obsidian:10>;
val EnderGenerator = <ExtraUtilities:generator:3>;
val PotionGenerator = <ExtraUtilities:generator:6>;

recipes.remove(TransfernodeLiquid);
recipes.addShaped(TransfernodeLiquid,[[null,TransferPipe,null],[Lapis,EnderPearl,Lapis],[VoidMetal,TitaniumBucket,VoidMetal]]);

recipes.remove(TransfernodeItems);
recipes.addShaped(TransfernodeItems,[[null,TransferPipe,null],[Redstone,EnderPearl,Redstone],[VoidMetal,IronChest,VoidMetal]]);

recipes.addShaped(EnderGenerator,[[EnderInfusedObsidian,EnderInfusedObsidian,EnderInfusedObsidian],[EnderInfusedObsidian,ResonatingIngot,EnderInfusedObsidian],[Thaumium,Redstone,Thaumium]]);
recipes.addShaped(PotionGenerator,[[PurpleObsidian,PurpleObsidian,PurpleObsidian],[PurpleObsidian,FluidicIngot,PurpleObsidian],[Thaumium,Redstone,Thaumium]]);
