import mods.auraCascade.Pylon;
import mods.botania.ManaInfusion;
import minetweaker.item.IItemStack;
import mods.botania.RuneAltar;
import mods.thaumcraft.Arcane;

val Cobblestone = <ore:cobblestone>;
val CobbleSlab = <ore:slabCobblestone>;
val CobblestoneWall = <minecraft:cobblestone_wall>;
val Mutandis = <witchery:ingredient:14>;
val PetalApothecary = <Botania:altar>;
val Anypetal = <Botania:petal:*>;
val ManaPylon = <Botania:pylon>;
val AuraIngotBlue = <aura:ingotBlue>;
val AuraIngotYellow = <aura:ingotYellow>;
val GoldNugget = <ore:nuggetGold>;
val ManaDiamond = <Botania:manaResource:2>;
val ManaSteel = <Botania:manaResource>;
val BloodRune = <AWWayofTime:AlchemicalWizardrybloodRune>;
val LivingRock = <Botania:livingrock>;
val AttunedStone = <witchery:ingredient:10>;
val ManaPearl = <Botania:manaResource:1>;
val RunicAltar = <Botania:runeAltar>;
val TerraSteelIngot = <Botania:manaResource:4>;
val AuraGemGreen = <aura:gemGreen>;
val NaturaPylon = <Botania:pylon:1>;
val TitaniumIngot = <Mariculture:materials:2>;
val ImpureTitaniumIngot = <Mariculture:materials:3>;
val ManaSteelBlock = <Botania:storage>;
val ImpureTitaniumBlock = <Mariculture:metals:2>;
val TitaniumBlock = <Mariculture:metals:4>;
val LivingWood = <Botania:livingwood>;
val HollowTears = <witchery:ingredient:115>;
val ElvenGateway = <Botania:alfheimPortal>;
val ArcanePrism = <aura:prismWhite>;
val SoulWorld = <witchery:ingredient:43>;
val BasicRunes = [<Botania:rune>,<Botania:rune:1>,<Botania:rune:2>,<Botania:rune:3>] as IItemStack[];
val AuraIngots = [<aura:ingotBlue>,<aura:ingotRed>,<aura:ingotGreen>,<aura:ingotWhite>] as IItemStack[];
val ChromaDusts = [<ChromatiCraft:chromaticraft_item_tiered:9>,<ChromatiCraft:chromaticraft_item_tiered:10>,<ChromatiCraft:chromaticraft_item_crafting:31>,<ChromatiCraft:chromaticraft_item_crafting:26>] as IItemStack[];
val ChromaShards = [<ChromatiCraft:chromaticraft_item_shard:6>,<ChromatiCraft:chromaticraft_item_shard:14>,<ChromatiCraft:chromaticraft_item_shard:2>,<ChromatiCraft:chromaticraft_item_shard:7>] as IItemStack[];
val ManaPowder = <Botania:manaResource:23>;
val ReinforcedSlate = <AWWayofTime:reinforcedSlate>;
val ManaRune = <Botania:rune:8>;
val AuraDust = <ChromatiCraft:chromaticraft_item_tiered:1>;
val AuraIngotViolet = <aura:ingotViolet>;
val BoostedZambarauShard = <ChromatiCraft:chromaticraft_item_shard:21>;
val TerraShatterer = <Botania:terraPick>;
val GaiaSpiritIngot = <Botania:manaResource:14>;
val DreamwoodRod = <Botania:manaResource:13>;
val PrimalCrusher = <Thaumcraft:ItemPrimalCrusher>;

recipes.remove(PetalApothecary);
recipes.addShaped(PetalApothecary,[[CobbleSlab,Anypetal,CobbleSlab],[Mutandis,CobblestoneWall,Mutandis],[Cobblestone,Cobblestone,Cobblestone]]);

recipes.remove(ManaPylon);
recipes.addShaped(ManaPylon,[[GoldNugget,AuraIngotYellow,GoldNugget],[ManaSteel,ManaDiamond,ManaSteel],[GoldNugget,AuraIngotBlue,GoldNugget]]);

recipes.remove(RunicAltar);
recipes.addShaped(RunicAltar,[[LivingRock,ManaPearl,LivingRock],[LivingRock,AttunedStone,LivingRock],[BloodRune,BloodRune,BloodRune]]);

recipes.remove(NaturaPylon);
Pylon.addRecipe(NaturaPylon, <aura:GREEN_AURA>*50000, TerraSteelIngot, <aura:GREEN_AURA>*50000, AuraGemGreen, <aura:GREEN_AURA>*50000, AuraGemGreen, <aura:GREEN_AURA>*50000, ManaPylon);

ManaInfusion.removeRecipe(ManaSteel);
ManaInfusion.addInfusion(ManaSteel,TitaniumIngot,3000);
ManaInfusion.addInfusion(ManaSteel,ImpureTitaniumIngot,7500);

ManaInfusion.removeRecipe(ManaSteelBlock);
ManaInfusion.addInfusion(ManaSteelBlock,TitaniumBlock,27000);
ManaInfusion.addInfusion(ManaSteelBlock,ImpureTitaniumBlock,67500);

recipes.remove(<AgriCraft:cropsItem>);
recipes.addShaped(<AgriCraft:cropsItem>*16,[[<Botania:manaResource:3>,<Botania:manaResource:3>],[<Botania:manaResource:3>,<Botania:manaResource:3>]]);

recipes.remove(ElvenGateway);
recipes.addShaped(ElvenGateway,[[LivingWood,HollowTears,LivingWood],[TerraSteelIngot,ArcanePrism,TerraSteelIngot],[LivingWood,SoulWorld,LivingWood]]);

for i, rune in BasicRunes {
    RuneAltar.removeRecipe(rune);
    RuneAltar.addRecipe(rune*3,[ReinforcedSlate,AuraIngots[i],ManaSteel,ManaPowder,ChromaDusts[i],ChromaShards[i]],6000);
}

RuneAltar.removeRecipe(ManaRune);
RuneAltar.addRecipe(ManaRune,[BoostedZambarauShard,AuraDust,AuraIngotViolet,ManaPearl,BoostedZambarauShard,AuraDust,AuraIngotViolet,ManaPearl],7500);

ManaInfusion.removeRecipe(<technom:itemBO>);
recipes.addShaped(<technom:itemBO>,[[null,null,<minecraft:redstone>],[null,ManaSteel,null],[<minecraft:redstone>,null,null]]);

recipes.remove(TerraShatterer);
Arcane.addShaped("ASPECTS",TerraShatterer,"perditio 50, terra 100", [[TerraSteelIngot,GaiaSpiritIngot,TerraSteelIngot],[TerraSteelIngot,PrimalCrusher,TerraSteelIngot],[null,DreamwoodRod,null]]);
