import mods.thaumcraft.Arcane;
import mods.thaumcraft.Research;
import mods.thaumcraft.Crucible;
import mods.thaumcraft.Infusion;

val KamiWandCore = <ThaumicTinkerer:kamiResource:5>;
val IchorCloth = <ThaumicTinkerer:kamiResource:1>;
val Ichorium = <ThaumicTinkerer:kamiResource:2>;
val Ichor = <ThaumicTinkerer:kamiResource>;
val SilverWoodWandCore = <Thaumcraft:WandRod:2>;
val BlazingRod = <Thaumcraft:WandRod:6>;
val BoneRod = <Thaumcraft:WandRod:7>;
val QuartzRod = <Thaumcraft:WandRod:4>;
val ObsidianRod = <Thaumcraft:WandRod:1>;
val IceRod = <Thaumcraft:WandRod:3>;
val ReedRod = <Thaumcraft:WandRod:5>;
val SalisMundus = <Thaumcraft:ItemResource:14>;
val BloodRod = <ForbiddenMagic:WandCores:3>;
val WitchWoodRod = <ForbiddenMagic:WandCores:4>;
val DreamWoodRod = <ForbiddenMagic:WandCores:11>;
val AmberRod = <ThaumicExploration:amberCore>;
val TransmutativeRod = <ThaumicExploration:transmutationCore>;
val TaintedRod = <ForbiddenMagic:WandCores>;
val InfernalRod = <ForbiddenMagic:WandCores:1>;
val PortalRift = <ChromatiCraft:chromaticraft_block_portal>;
val GluttonyShard = <ForbiddenMagic:GluttonyShard>;
val WrathShard = <ForbiddenMagic:NetherShard>;
val EnvyShard = <ForbiddenMagic:NetherShard:1>;
val PrideShard = <ForbiddenMagic:NetherShard:3>;
val LustShard = <ForbiddenMagic:NetherShard:4>;
val SlothShard = <ForbiddenMagic:NetherShard:5>;
val GreedShard = <ForbiddenMagic:NetherShard:6>;
val NetherShard = <ThaumicTinkerer:kamiResource:6>;
val EndShard = <ThaumicTinkerer:kamiResource:7>;
val FloatStone = <ChromatiCraft:chromaticraft_item_dimgen:1>;
val CrystalCluster = <AWWayofTime:blockCrystal>;
val ArcanePrism = <aura:prismWhite>;
val PrimalFocus = <Thaumcraft:FocusPrimal>;
val SubduedSpirit = <witchery:ingredient:112>;
val DemonHeart = <witchery:ingredient:23>;
val PureEssence = <arsmagica2:essence:10>;
val GaiaSpirit = <Botania:manaResource:5>;
val EnchantingDrop = <MagicBees:drop>;
val AwakenedKamiPickaxe = <ThaumicTinkerer:ichorPickGem>; 
val AwakenedKamiAxe = <ThaumicTinkerer:ichorAxeGem>;
val AwakenedKamiShovel = <ThaumicTinkerer:ichorShovelGem>;
val ExcavationFocus = <Thaumcraft:FocusExcavation>;
val DraconiumNativeCluster = <aobd:clusterDraconium>;
val CobaltNativeCluster = <WitchingGadgets:item.WG_Cluster:1>;
val ArditeNativeCluster = <WitchingGadgets:item.WG_Cluster:2>;
val BindingCatalystPick = <arsmagica2:bindingCatalyst>;
val BindingCatalystAxe = <arsmagica2:bindingCatalyst:1>;
val BindingCatalystShovel = <arsmagica2:bindingCatalyst:3>;
val PickaxeOfTheCore = <Thaumcraft:ItemPickaxeElemental>;
val AxeOfTheStream = <Thaumcraft:ItemAxeElemental>;
val ShovelOfTheEarthMover = <Thaumcraft:ItemShovelElemental>;
val TerraShatterer = <Botania:terraPick>;
val ShovelPurifier = <ForbiddenMagic:TaintShovel>;
val TerraTruncator = <Botania:terraAxe>;
val ExcavationStar = <ChromatiCraft:chromaticraft_item_excavator>;
val TransitationStar = <ChromatiCraft:chromaticraft_item_transition>;
val GrowthStar = <ChromatiCraft:chromaticraft_item_growth>;
val MineralEnricher = <ChromatiCraft:chromaticraft_item_adjacency:3>.withTag({tier: 4});
val EnergyBooster = <ChromatiCraft:chromaticraft_item_adjacency:11>.withTag({tier: 4});
val RedHole = <aura:redHole>;
val PickaxeAngelSteel1 = <aura:angelsteelPickaxe0>;
val AxeAngelSteel1 = <aura:angelsteelAxe0>;
val ShovelAngelSteel1 = <aura:angelsteelShovel0>;
val PickaxeHeadChromastone = <TConstruct:pickaxeHead:90>;
val AxeHeadChromastone = <TConstruct:hatchetHead:90>;
val ShovelHeadChromastone = <TConstruct:shovelHead:90>;
val KamiPickaxe = <ThaumicTinkerer:ichorPick>;
val KamiAxe = <ThaumicTinkerer:ichorAxe>;
val KamiShovel = <ThaumicTinkerer:ichorShovel>;
val AlchemicalCap = <ForbiddenMagic:WandCaps>;
val VinteumCap = <ForbiddenMagic:WandCaps:1>;
val ElementiumCap = <ForbiddenMagic:WandCaps:5>;
val MechanistsCap = <ThaumicExploration:mechanistCap>;
val SojournersCap = <ThaumicExploration:sojournerCap>;
val FireCap = <ChromatiCraft:chromaticraft_item_modinteract:1>;
val WaterCap = <ChromatiCraft:chromaticraft_item_modinteract:2>;
val EnderCap = <ChromatiCraft:chromaticraft_item_modinteract:3>;
val ChargedVoidCap = <Thaumcraft:WandCap:7>;
val KamiCap = <ThaumicTinkerer:kamiResource:4>;
val AwakenedKamiHood = <ThaumicTinkerer:ichorclothHelmGem>;
val KamiHood = <ThaumicTinkerer:ichorclothHelm>;
val ShadowFortressHelmet = <TaintedMagic:ItemShadowFortressHelmet>;
val DeathHood = <witchery:deathscowl>;
val TerrasteelHelmet = <Botania:terrasteelHelm>;
val ProtectionCore = <ChromatiCraft:chromaticraft_item_adjacency:1>.withTag({tier: 4});
val CapacityCore = <ChromatiCraft:chromaticraft_item_adjacency:6>.withTag({tier: 4});
val VadaliUpgradedPendant = <ChromatiCraft:chromaticraft_item_pendant3:6>;
val ProtectionAmuletBlue = <aura:blueAmulet>;
val KitrinoUpgradedPendant = <ChromatiCraft:chromaticraft_item_pendant3:11>;
val ProtectionAmuletYellow = <aura:yellowAmulet>;
val TerrasteelChestplate = <Botania:terrasteelChest>;
val DeathRobes = <witchery:deathsrobe>;
val KamiRobes = <ThaumicTinkerer:ichorclothChest>;
val AwakenedKamiRobes = <ThaumicTinkerer:ichorclothChestGem>;
val ShadowFortressCuirass = <TaintedMagic:ItemShadowFortressChestplate>;
val BootsOfTheMeteor = <ThaumicExploration:bootsMeteor>;
val DeathBoots = <witchery:deathsfeet>;
val TerrasteelBoots = <Botania:terrasteelBoots>;
val RangeExpander = <ChromatiCraft:chromaticraft_item_adjacency:10>.withTag({tier: 4});
val AsvesteUpgradedPendant = <ChromatiCraft:chromaticraft_item_pendant3:10>;
val ProtectionAmuletGreen = <aura:greenAmulet>;
val KamiBoots = <ThaumicTinkerer:ichorclothBoots>;
val AwakenedKamiBoots = <ThaumicTinkerer:ichorclothBootsGem>;
val ShadowFortressThighGuards = <TaintedMagic:ItemShadowFortressLeggings>;
val GulgsGurdle = <witchery:gurdleofgulg>;
val TerrasteelLeggings = <Botania:terrasteelLegs>;
val HeatRelay = <ChromatiCraft:chromaticraft_item_adjacency:14>.withTag({tier: 4});
val PortokaliUpgradedPendant = <ChromatiCraft:chromaticraft_item_pendant3:14>;
val ProtectionAmuletRed = <aura:redAmulet>;
val KamiLeggings = <ThaumicTinkerer:ichorclothLegs>;
val AwakenedKamiLeggings = <ThaumicTinkerer:ichorclothLegsGem>;
val CelestialPearl = <ThaumicTinkerer:skyPearl>;
val LapisBlock = <minecraft:lapis_block>;
val Diamond = <minecraft:diamond>;
val EnderPearl = <minecraft:ender_pearl>;
val DemonicBlood = <witchery:ingredient:80>;

mods.thaumcraft.Aspects.add(Ichor,"terminus 4");
Infusion.removeRecipe(KamiWandCore);
Infusion.addRecipe("ROD_ICHORCLOTH", SilverWoodWandCore, [BloodRod,WitchWoodRod,Ichor,SalisMundus,DreamWoodRod,SalisMundus,Ichor,IchorCloth,ObsidianRod,IceRod,Ichor,SalisMundus,BoneRod,SalisMundus,Ichor,AmberRod,IchorCloth,TransmutativeRod,Ichor,SalisMundus,BlazingRod,SalisMundus,Ichor,QuartzRod,ReedRod,IchorCloth,Ichor,SalisMundus,TaintedRod,SalisMundus,Ichor,InfernalRod], "praecantatio 128, lux 32, instrumentum 16, potentia 32", KamiWandCore, 10);
Research.refreshResearchRecipe("ROD_ICHORCLOTH");

Infusion.removeRecipe(Ichor);
Infusion.addRecipe("ICHOR", PortalRift, [GluttonyShard,WrathShard,EnvyShard,PrideShard,LustShard,SlothShard,GreedShard,NetherShard,EndShard,FloatStone,CrystalCluster,ArcanePrism,PrimalFocus,SubduedSpirit,DemonicBlood,PureEssence,GaiaSpirit,EnchantingDrop],"spiritus 64, humanus 32, lux 32", Ichor*16, 7);
Research.refreshResearchRecipe("ICHOR");

Infusion.removeRecipe(AwakenedKamiPickaxe);
Infusion.addRecipe("ICHOR_PICK_GEM",KamiPickaxe, [IchorCloth,Ichor,Ichorium,ExcavationFocus,DraconiumNativeCluster,CobaltNativeCluster,ArditeNativeCluster,BindingCatalystPick,PickaxeOfTheCore,TerraShatterer,ExcavationStar,MineralEnricher,EnergyBooster,RedHole,PickaxeAngelSteel1,PickaxeHeadChromastone],"perfodio 64, ignis 50, metallum 32, terra 32, meto 32, lucrum 16, sensus 16",AwakenedKamiPickaxe,15);
Research.refreshResearchRecipe("ICHOR_PICK_GEM");

Infusion.removeRecipe(AwakenedKamiShovel);
Infusion.addRecipe("ICHOR_SHOVEL_GEM",KamiShovel, [IchorCloth,Ichor,Ichorium,ExcavationFocus,DraconiumNativeCluster,CobaltNativeCluster,ArditeNativeCluster,BindingCatalystShovel,ShovelOfTheEarthMover,ShovelPurifier,TransitationStar,MineralEnricher,EnergyBooster,RedHole,ShovelAngelSteel1,ShovelHeadChromastone],"terra 82, perfodio 64, instrumentum 32, meto 32, vinculum 16, sensus 16",AwakenedKamiShovel,15);
Research.refreshResearchRecipe("ICHOR_SHOVEL_GEM");

Infusion.removeRecipe(AwakenedKamiAxe);
Infusion.addRecipe("ICHOR_AXE_GEM",KamiAxe, [IchorCloth,Ichor,Ichorium,ExcavationFocus,DraconiumNativeCluster,CobaltNativeCluster,ArditeNativeCluster,BindingCatalystAxe,AxeOfTheStream,TerraTruncator,GrowthStar,MineralEnricher,EnergyBooster,RedHole,AxeAngelSteel1,AxeHeadChromastone],"aqua 50, perfodio 64, instrumentum 32, arbor 32, meto 32, messis 16, sensus 16",AwakenedKamiAxe,15);
Research.refreshResearchRecipe("ICHOR_AXE_GEM");

Arcane.removeRecipe(KamiCap);
Infusion.addRecipe("CAP_ICHOR",ChargedVoidCap,[AlchemicalCap,Ichorium,SalisMundus,VinteumCap,SalisMundus,Ichor,ElementiumCap,Ichorium,SalisMundus,MechanistsCap,SalisMundus,Ichor,SojournersCap,Ichorium,SalisMundus,FireCap,SalisMundus,Ichor,WaterCap,Ichorium,SalisMundus,EnderCap,SalisMundus,Ichor],"praecantatio 128, lux 32, auram 16, potentia 32",KamiCap*2,10);
Research.clearPages("CAP_ICHOR");
Research.addPage("CAP_ICHOR", "ttresearch.page.CAP_ICHOR.0");
game.setLocalization("en_US", "ttresearch.page.CAP_ICHOR.ttresearch.page.CAP_ICHOR.ttresearch.page.CAP_ICHOR.0","You have put Ichorium to its first ever use, by devising wand caps that give you a 30% discount on everything. Now you need to actually put this to any use and create a wand that can store more vis.");
Research.addInfusionPage("CAP_ICHOR",KamiCap);

Infusion.removeRecipe(AwakenedKamiHood);
Infusion.addRecipe("ICHORCLOTH_HELM_GEM",KamiHood,[ShadowFortressHelmet,DeathHood,TerrasteelHelmet,ProtectionCore,CapacityCore,Ichor,Ichor,Ichor,VadaliUpgradedPendant,ProtectionAmuletBlue],"lux 64, aqua 64, tutamen 32, fames 32, auram 32, corpus 16, cognitio 16", AwakenedKamiHood, 15);
Research.refreshResearchRecipe("ICHORCLOTH_HELM_GEM");

Infusion.removeRecipe(AwakenedKamiRobes);
Infusion.addRecipe("ICHORCLOTH_CHEST_GEM",KamiRobes,[ShadowFortressCuirass,DeathRobes,TerrasteelChestplate,ProtectionCore,EnergyBooster,Ichor,Ichor,Ichor,KitrinoUpgradedPendant,ProtectionAmuletYellow], "lux 64, aer 64, tutamen 32, volatus 32, ordo 32, alienis 16, sensus 16", AwakenedKamiRobes, 15);
Research.refreshResearchRecipe("ICHORCLOTH_CHEST_GEM");

Infusion.removeRecipe(AwakenedKamiBoots);
Infusion.addRecipe("ICHORCLOTH_BOOTS_GEM",KamiBoots,[BootsOfTheMeteor,DeathBoots,TerrasteelBoots,ProtectionCore,RangeExpander,Ichor,Ichor,Ichor,AsvesteUpgradedPendant,ProtectionAmuletGreen],"lux 64, terra 64, tutamen 32, perfodio 32, motus 32, herba 16, iter 16", AwakenedKamiBoots, 15);
Research.refreshResearchRecipe("ICHORCLOTH_BOOTS_GEM");

Infusion.removeRecipe(AwakenedKamiLeggings);
Infusion.addRecipe("ICHORCLOTH_LEGS_GEM", KamiLeggings,[ShadowFortressThighGuards,GulgsGurdle,TerrasteelLeggings,ProtectionCore,HeatRelay,Ichor,Ichor,Ichor,PortokaliUpgradedPendant,ProtectionAmuletRed],"lux 64, ignis 64, tutamen 32, sano 32, potentia 32, lucrum 16, alienis 16", AwakenedKamiLeggings, 15);
Research.refreshResearchRecipe("ICHORCLOTH_LEGS_GEM");

Infusion.removeRecipe(CelestialPearl);
Infusion.addRecipe("WARP_GATE",EnderPearl,[Ichor,EndShard,LapisBlock,Diamond],"iter 32, alienis 32, volatus 32, aer 16",CelestialPearl * 4, 7);
Research.refreshResearchRecipe("WARP_GATE");
