# Author: Atricos
print("STARTING Fixes.zs");

# Ball of Moss recipe interfered with a DivineRPG recipe
recipes.removeShaped(<TConstruct:materials:6>, [[<ore:stoneMossy>, <ore:stoneMossy>, <ore:stoneMossy>], [<ore:stoneMossy>, <ore:stoneMossy>, <ore:stoneMossy>], [<ore:stoneMossy>, <ore:stoneMossy>, <ore:stoneMossy>]]);
recipes.addShaped(<TConstruct:materials:6>, [[<ore:stoneMossy>, <ore:stoneMossy>, <ore:stoneMossy>], [<ore:stoneMossy>, null, <ore:stoneMossy>], [<ore:stoneMossy>, <ore:stoneMossy>, <ore:stoneMossy>]]);

# Convert Wheat into Seeds
recipes.addShapeless(<minecraft:wheat_seeds> * 3, [<minecraft:wheat>, <minecraft:wheat>, <minecraft:wheat>]);

# Recipe fix for Smooth Blackstone -> Paved Blackstone
recipes.removeShapeless(<minecraft:stone_button>, [<MineFactoryReloaded:stone>]);
recipes.addShapeless(<minecraft:stone_button>, [<minecraft:stone>]);

# Minecart Duplication Fix
recipes.remove(<minecraft:minecart>);
recipes.addShaped(<minecraft:minecart>,[[<minecraft:iron_ingot>, null, <minecraft:iron_ingot>],[<minecraft:iron_ingot>, <minecraft:iron_ingot>, <minecraft:iron_ingot>],[null, null, null]]);

# Tinkers' Table conversions to Oak varients to be able to complete quests
recipes.remove(<TConstruct:CraftingSlab:3>);
recipes.addShapeless(<TConstruct:CraftingSlab:3>, [<TConstruct:ToolStationBlock:10>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:10>, [<TConstruct:ToolStationBlock:11>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:10>, [<TConstruct:ToolStationBlock:12>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:10>, [<TConstruct:ToolStationBlock:13>]);
recipes.remove(<TConstruct:CraftingSlab:2>);
recipes.addShapeless(<TConstruct:CraftingSlab:2>, [<TConstruct:ToolStationBlock:1>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:1>, [<TConstruct:ToolStationBlock:2>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:1>, [<TConstruct:ToolStationBlock:3>]);
recipes.addShapeless(<TConstruct:ToolStationBlock:1>, [<TConstruct:ToolStationBlock:4>]);
<TConstruct:ToolStationBlock:11>.addTooltip(format.aqua("Can be converted into the Oak varient."));
<TConstruct:ToolStationBlock:12>.addTooltip(format.aqua("Can be converted into the Oak varient."));
<TConstruct:ToolStationBlock:13>.addTooltip(format.aqua("Can be converted into the Oak varient."));
<TConstruct:ToolStationBlock:2>.addTooltip(format.aqua("Can be converted into the Oak varient."));
<TConstruct:ToolStationBlock:3>.addTooltip(format.aqua("Can be converted into the Oak varient."));
<TConstruct:ToolStationBlock:4>.addTooltip(format.aqua("Can be converted into the Oak varient."));

# Iron Armor bug fixes
mods.thaumcraft.Arcane.addShaped("RESEARCH", <Thaumcraft:ItemGolemDecoration:5>, "terra 4, aqua 4", [[<minecraft:iron_ingot>,<divinerpg:ironHelmet>,<minecraft:iron_ingot>],[null,null,null],[null,null,null]]);
recipes.addShaped(<OpenBlocks:sonicglasses>, [[<minecraft:iron_ingot>,<divinerpg:ironHelmet>,<minecraft:iron_ingot>],[<minecraft:obsidian>,<ore:stickWood>,<minecraft:obsidian>]]);
mods.thaumcraft.Arcane.addShaped("RESEARCH", <Thaumcraft:ItemGolemDecoration:6>, "terra 8", [[<minecraft:iron_ingot>,null,<minecraft:iron_ingot>],[<minecraft:iron_ingot>,<divinerpg:ironChestplate>,<minecraft:iron_ingot>],[null,null,null]]);

# EnergizedCrystal -> Energized Crystal namefix
<quantumflux:energizedCrystal>.displayName = "Energized Crystal";

# Nickel, Platinum -> Ferrous, Shiny namechanges
<magicalcrops:NickelSeeds>.displayName = "Ferrous Seeds";
<magicalcrops:PlatinumSeeds>.displayName = "Shiny Seeds";
<magicalcrops:NickelEssence>.displayName = "Ferrous Essence";
<magicalcrops:PlatinumEssence>.displayName = "Shiny Essence";
<MineFactoryReloaded:upgrade.radius:9>.displayName = "Upgrade (Shiny)";

# Dice of Faith Quest recognition
recipes.addShapeless(<Botania:dice>, [<Botania:dice>]);
<Botania:dice>.addTooltip(format.red("Dropped by the Gaia Guardian II."));
<Botania:dice>.addTooltip(format.aqua("If you're having trouble completing"));
<Botania:dice>.addTooltip(format.aqua("the quest for this item, use a Crafting"));
<Botania:dice>.addTooltip(format.aqua("Table to remove all NBT from it."));

# Disabled Project Red Auto Crafting Bench because of client crash
recipes.remove(<ProjRed|Expansion:projectred.expansion.machine2:11>);

print("ENDING Fixes.zs");
