# Author: Atricos
print("STARTING MinecraftRecipes.zs");

# Early game recipes
recipes.remove(<minecraft:furnace>);
recipes.addShaped(<minecraft:furnace>, [[<minecraft:stone_slab:3>,<minecraft:stone_slab:3>,<minecraft:stone_slab:3>],[<ExtraUtilities:cobblestone_compressed>,<minecraft:coal>,<ExtraUtilities:cobblestone_compressed>],[<minecraft:stone_slab:3>,<minecraft:stone_slab:3>,<minecraft:stone_slab:3>]]);
recipes.remove(<minecraft:bucket>);
recipes.addShaped(<minecraft:bucket>, [[<minecraft:iron_ingot>,null,<minecraft:iron_ingot>],[null,<minecraft:heavy_weighted_pressure_plate>,null]]);
recipes.remove(<minecraft:chest>);
recipes.addShaped(<minecraft:chest>, [[<ore:plankWood>,<ore:logWood>,<ore:plankWood>],[<ore:plankWood>,null,<ore:plankWood>],[<ore:plankWood>,<ore:plankWood>,<ore:plankWood>]]);
recipes.addShaped(<minecraft:chest>, [[<minecraft:planks:0>,<minecraft:log:0>,<minecraft:planks:0>],[<minecraft:planks:0>,null,<minecraft:planks:0>],[<minecraft:planks:0>,<minecraft:planks:0>,<minecraft:planks:0>]]);
recipes.removeShaped(<minecraft:piston>);
recipes.addShaped(<minecraft:piston>, [[<ore:plankWood>,<ore:plankWood>,<ore:plankWood>],[<ore:cobblestone>,<ore:logWood>,<ore:cobblestone>],[<minecraft:redstone>,<minecraft:heavy_weighted_pressure_plate>,<minecraft:redstone>]]);
recipes.removeShaped(<minecraft:wheat> * 9, [[<minecraft:hay_block>]]);

# Mushroom Stew conversion
recipes.addShapeless(<minecraft:mushroom_stew>, [<Natura:natura.stewbowl>]);
recipes.addShapeless(<Natura:natura.stewbowl>, [<minecraft:mushroom_stew>]);

# Eye of Ender
recipes.remove(<minecraft:ender_eye>);
mods.thermalexpansion.Smelter.addRecipe(6000, <minecraft:ender_pearl>, <minecraft:blaze_powder>, <minecraft:ender_eye>);

# Beacon
recipes.remove(<minecraft:beacon>);
recipes.addShaped(<minecraft:beacon>, [[<minecraft:glass>,<minecraft:nether_star>,<minecraft:glass>],[<minecraft:glass>,<Botania:manaResource:2>,<minecraft:glass>],[<minecraft:obsidian>,<minecraft:obsidian>,<minecraft:obsidian>]]);

# Diamond Horse Armor processing
mods.appeng.Grinder.addRecipe(<minecraft:diamond_horse_armor>, <minecraft:diamond> * 5, 6);

# End Portal Frame
val orb = <ore:CreativeOrbs>;
orb.add(<AWWayofTime:creativeFiller>);
orb.add(<Avaritia:Orb_Armok>);
recipes.addShaped(<minecraft:end_portal_frame> * 4, [[<runicdungeons:item.earthCrystal>,<Avaritia:Singularity:1>,<runicdungeons:item.earthCrystal>],[<minecraft:end_stone>,orb,<minecraft:end_stone>],[<minecraft:end_stone>,<customthings:block0:14>,<minecraft:end_stone>]]);

print("ENDING MinecraftRecipes.zs");